ティラノビルダー交流掲示板 187957


ノベルゲーム制作ツール、「ティラノビルダー」に関する掲示板です
ティラノスクリプトに関する質問等はティラノ交流掲示板でお願いします。

質問を書き込む前に

こんな機能ないかな?と思った時
ティラノスクリプトのタグリファレンス

ティラノWikiも確認
http://tyrano.wiki.fc2.com/

バグ報告や質問、要望などご自由にお使い下さい。


CGモードの作りかた

1:のの :

2015/09/23 (Wed) 23:19:45

ティラノビルダーでCGモード(未完全ですが)を作る方法。
もしもすでに説明されている方がいたらごめんなさい。
自分も最近いじったばかりなので参考程度にどうぞ。

1.CGモードに追加したいCGを「myproject」の「bgimage」に入れておく。
2.「scenario」フォルダの中にある「system」フォルダに「nove_booster.ks」があるはずなので
 それを開くと、

*CGモードで表示されるCG一覧を登録*/

tf.cg_array = ["",];

みたいな感じの文字があるので["",]の中にCGとして表示したいファイル名を随時記入。
ちなみに一つずつ入れてくださいね。 例)["room.jpg", "rouka.jpg",]

3.公式からアップされている「爆速☆ノベルゲーム開発ブースターパック」をダウンロードして
 「cg.ks」をコピーし、作っているゲームの「scenario」フォルダの中に入れます。
 また、後々のためにブースターパックに入っている
「cgbg.png」「noise.jpg」「back_title.gif」を制作ゲームの「bgimage」にコピーしておきましょう。

(以下少しややこしくなるので注意)
4.コピーした「cg.ks」を開いて下にスクロールすると
*backtitle
[cm]
[freeimage layer=1]
@jump storage=title.ks

というものがあると思います。
しかしビルダーで作成すると「title_screen.ks」がタイトルなので以下のように変更します。

*backtitle
[cm]
[freeimage layer=1]
@jump storage=title_screen.ks

画面サイズの関係でバックタイトルボタンが表示されない人は
*cgpage
[cm]
[button graphic="back_title.gif" target="*backtitle" x=800 y=20 ]
の中のxの数字をいじればいいと思います。
これでタイトルに戻るためのボタンができるはずです。

5.次はタイトル画面にシンプルなCGモードボタンを作りたいと思います。
 いったん「cg.ks」を閉じて「title_screen.ks」を開きます。
 そこに

[glink text="はじめから" x=400 y=270 size=20 target="*start"]

  といった記述があると思うのでその下に好みの数字で

     [glink text="ギャラリー" x= y= target="*cg"]

  といれましょう。このままだとギャラリーのページに飛ばないので同じく
 「title_screen.ks」の一番下に以下のファイルを書き込みます。

;----------CGモードが選択された時
*cg
[jump storage="cg.ks"]
[s]

これでどうにかCGページに飛ぶと思います。

6.最後に該当するCGが表示された後に打ち込むスクリプトを入れます。
 ここではティラノビルダーを使います。
 理由は原因は不明ですが、ksファイルに直接書き込んでも反映されないからです。
 
 CGを表示したコンポーネントの下に「ティラノスクリプト」コンポーネントを
 ドラッグ&ドロップします。
 その中に
[cg storage="(任意の画像)" ]
 を入れます。
 すると見終わった後CGモードに行くと画像が表示されるはずです。

ただしこの方法ではまだ画面サイズの変更に対応できていないので、
まだまだ改善策を探しております。
2:のの :

2015/09/24 (Thu) 17:10:55

ちなみにver.は1.30です。
3:むずかしい! :

2015/09/26 (Sat) 21:56:26

記述通りにやってみましたが、砂荒らしの画像のままで何も起きないです・・・
砂嵐画像をクリックすると、一瞬背景が透けて見えるだけです。
4:のの :

2015/09/27 (Sun) 13:39:45

3>>
それはクリックして表示すべき画像は一瞬出るけどすぐに
消えてしまう状態でしょうか?

仮にそうだとしたらスキップ機能がonになっている可能性があるので
offにしてから確認をお願いします。
5:のの :

2015/09/27 (Sun) 15:21:07

こんにちは。
申し訳ないのですが、以前書いたCGモードの作りかたについて間違った
記述をしたところがあったので訂正します。

間違っていた箇所は3番の『「back_title.gif」を「bgimage」に入れる』ところです。
正しくは「image」フォルダに入れるでした。

そちらに入れないと正しくボタンが表示されません。
失礼いたしました。
6:3です。 :

2015/09/27 (Sun) 18:40:47

でるべき画像は現れませんでした。
novel_booster.ksの中身は

________________________________________

[_tb_system_call storage=system/_novel_booster.ks]

[iscript]
tf.flag_replay = false;
/*CGモードで表示されるCG一覧を登録*/
tf.cg_array = [
"sakura.jpg",
"himawari.jpg",
"ayame.jpg",
"hakobe.jpg",
"syungiku.jpg",
];
tf.replay_array = [
{image:"cat.jpg",storage:"event.ks",target:"replay_scene1"},
{image:"entrance.jpg",storage:"scenario1.ks",target:"replay_scene2"},
{image:"rouka.jpg",storage:"scenario1.ks",target:"replay_scene3"},
{image:"toile.jpg",storage:"scenario1.ks",target:"replay_scenetmp"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"},
{image:"room.jpg",storage:"scenario1.ks",target:"replay_scenet"}
];
if(sf.cg_viewd){
}else{
sf.cg_viewd = {};
}
if(sf.replay_viewd){
}else{
sf.replay_viewd = {};
}
[endscript]

[macro name="cg" ]

[iscript]
sf.cg_viewd[mp.storage] = "on";
[endscript]

[endmacro]

[macro name="endreplay"]

[if exp="tf.flag_replay == true"]

[layopt page="fore" layer="message0" visible=false]

[hidemenubutton]

[jump storage="replay.ks" target="" ]
[endif]

[endmacro]

[macro name="setreplay"]

[iscript]
sf.replay_viewd[mp.name] = "on";
[endscript]

[endmacro]


____________________________________________________


このようになっています。
そしてティラノビルダーでシナリオを開き、ギャラリーに表示したい画像の下に

灰色のティラノスクリプトの入力欄をつくり、

@cg storage="sakura.jpg"

と入れています。

これではまずいのでしょうか?ギャラリーのページには砂嵐のマスが並んでいて
見せたい画像のサムネイル等も出ません。アプリに書き出してみても同様でした。

パソコンはMACでPro版を使っています。
7:のの :

2015/09/27 (Sun) 21:03:04

>>6
素人目ですがざっと自分のスクリプトと見比べたところ、大きな違いはありませんでした。

考えられる可能性としては

1.よく見るとファイル名を間違えている。
2.(各自プロジェクト名)フォルダ→「data」フォルダ→「bgimage」の中に表示したい画像を入れ忘れている。

おそらく違うとは思いますが、ざっと思いつくところはこんな感じです。

一つ確認しておきたいのですが、
テストプレイでCGを回収してからギャラリーモードを見ていますよね?
確認しないと表示されない仕様のようなので。
8:のの :

2015/09/27 (Sun) 22:43:11

ちょっと関係があるかわからないんですけどティラノビルダーで
CGを表示させるときのコンポーネントは「背景変更」で行ってます。
9:3です。 :

2015/09/28 (Mon) 20:51:55

アプリ形式で書き出してゲームを進めて行き、表示させたい画像が出て
@cg storage="sakura.jpg" のスクリプトを過ぎたと思われる所でセーブし
タイトルに戻りギャラリーを見たのですがダメでした。
10:3です。 :

2015/09/28 (Mon) 21:45:33

再び登場ですw
何の拍子かわかりませんが、ギャラリー表示できるようになりました!
ありがとうございました!

サムネイルの縦横比の調整等、私も探ってみたいと思います。
11:3です。 :

2015/09/28 (Mon) 22:15:10

しつこくてすいません。

画像の比率に関しては、cg.ksの

ーーーーーーーーーーーーーーーーーー

*cgview

[if exp ="sf.cg_viewd[tf.cg_array[tf.cg_index]]" ]

[button graphic=&tf.cg_array[tf.cg_index] x=&tf.left y=&tf.top width=160 height=120 exp="tf.selected_cg_image = tf.cg_array[preexp]" target="*clickcg" folder="bgimage" preexp="tf.cg_index" ]

[else]

[button graphic=noise.jpg x=&tf.left y=&tf.top width=160 height=120 folder="bgimage" target="*no_image"]


ーーーーーーーーーーーーーーーーーー


width=160 height=120 がサムネイルのピクセル数なので
用意してある画像と同じ比率(たとえば wが160 hが107等)にすると
キレイに縮小されたサムネイルが表示されます。

背景画像を変えたり、noise.jpgを他の好みの画像と差し替えたりすると、無機質なCGモードが
一気に華やかになりますね。

座標を変えると表示位置も変更できるようですが、ティラノビルダーで行うと何故かおかしくなるので
メモ帳などで開いて直接打った方が良いと思います。
12:おもち :

2015/09/30 (Wed) 10:53:08

はじめまして、CGモードの作り方、大変参考になりました。
私でも表示させることができて感激しています!

作っていて一つこうしたいな、という点が出てきたので、どなたかお分かりの方がいましたら、教えていただけると助かります。

スチルを3つ見たら自動的におまけスチルが現れる→CGモードの4番目の暗い部分が表示される
というふうにするにはどうしたらいいでしょうか。

=================================================

[_tb_system_call storage=system/_scene1.ks]

[cm ]
[bg storage="room.jpg" time="1000" ]
[tb_show_message_window ]
これはおまけモードのテストです。[p]


[bg time="3000" method="crossfade" storage="a.jpg" ]
[tb_start_tyrano_code]
@cg storage="a.jpg"

[_tb_end_tyrano_code]

次はスチルサンプルb[p]


[bg time="3000" method="crossfade" storage="b.jpg" ]
[tb_start_tyrano_code]
@cg storage="b.jpg"

[_tb_end_tyrano_code]

ラスト、スチルサンプルc[p]


[bg time="3000" method="crossfade" storage="c.jpg" ]
[tb_start_tyrano_code]
@cg storage="c.jpg"

[_tb_end_tyrano_code]

この3つのスチルを全部見た時に限り、おまけスチル4が見れるように設定したいです。[p]


[jump storage="title_screen.ks" target="*title" ]
[s ]


==========================================================


ver.は1.30、winで制作しています。

どうぞよろしくお願いします。
13:のの :

2015/09/30 (Wed) 21:22:21

>>10
無事表示されたようでよかったです。
画像比率も参考にさせていただきます。
14:のの :

2015/09/30 (Wed) 21:37:57

>>12
フラグを使ってみたらいかがですか?
15:dd :

2015/10/13 (Tue) 19:44:50

http://bbs8.fc2.com//bbs/img/_811700/811649/full/811649_1444733091.jpg こんにちは。CGモードについて質問です。
ブースターパックなどを参考にして作ってみたのですが、画像のようにスチル画像が見れません。
スチル二枚分開いたのですが画像が見つからないのか左上二枚のようになります…。
画像はbgimageに入れてます。回想モードに関する部分を邪魔だと思って消したのが原因でしょうか…。

アドバイスをいただけたらな、と思います。よろしくお願いします。

novel_booster.ksの中身は↓
--------------------------------------

;CGモード、登録すべき画像ファイル一覧

[iscript]

tf.flag_replay = false;

/*CGモードで表示されるCG一覧を登録*/

tf.cg_array = [


"6.png",
"7.png",
"8.png",
"9.png",
"10.png",
"11.png",
"12.png",



];

/*

回想モードに登録される
image = 回想モードで表示される画像を指定できます。
storageとtarget = 回想の開始地点位置をファイルとラベルを指定します

*/


if(sf.cg_viewd){
}else{
sf.cg_viewd = {};
}

[endscript]

;CGが閲覧された場合、CGモードで表示できるようにする
[macro name="cg" ]

[iscript]

sf.cg_viewd[mp.storage] = "on";

[endscript]

[endmacro]

-----------------------

CG閲覧ページの中身↓
----------------------

[_tb_system_call storage=system/_gallery.ks]

[cm ]
[bg time="300" method="crossfade" storage="title.jpg" ]
[tb_start_tyrano_code]
[layopt layer=1 visible=true]
[_tb_end_tyrano_code]

[iscript]
tf.page = 0;
tf.cg_index = 0;
tf.cg_length = tf.cg_array.length;
tf.selected_cg_image = ""; //選択されたCGを一時的に保管
[endscript]

*cgpage

[cm ]
[button graphic="menu_button_close.png" target="*backtitle" x="850" y="20" storage="gallery.ks" width="64" height="64" ]
[iscript]
tf.tmp_index = 0;
tf.cg_index = 12 * tf.page;
tf.top = 100;
tf.left = 60;
[endscript]

*cgview

[tb_start_tyrano_code]
[if exp ="sf.cg_viewd[tf.cg_array[tf.cg_index]]" ]
[button graphic=&tf.cg_array[tf.cg_index] x=&tf.left y=&tf.top width=160 height=140 exp="tf.selected_cg_image = tf.cg_array[preexp]" target="*clickcg" folder="default" preexp="tf.cg_index" ]
[else]
[button graphic=noise.png x=&tf.left y=&tf.top width=160 height=140 folder="image" target="*no_image"]
[endif]
[_tb_end_tyrano_code]

[iscript]
tf.tmp_index++;
tf.cg_index++;
tf.left += 160 + 60;
[endscript]

[tb_start_tyrano_code]
[if exp=" tf.tmp_index == 12 || tf.cg_index >= tf.cg_length"]
[_tb_end_tyrano_code]

[jump target="*endpage" storage="" ]
[tb_start_tyrano_code]
[endif]

[if exp="tf.tmp_index % 4 == 0 "]
[_tb_end_tyrano_code]

[iscript]
tf.top += 140 + 30;
tf.left = 60;
[endscript]

[tb_start_tyrano_code]
[endif]
[_tb_end_tyrano_code]

[jump target="*cgview" storage="" ]
*endpage

[tb_start_tyrano_code]
[if exp="tf.page !=0"]
[_tb_end_tyrano_code]

[button target="*backpage" graphic="arrow_back.png" x="750" y="590" storage="" width="50" height="50" ]
[tb_start_tyrano_code]
[endif]
[if exp="tf.cg_length > tf.cg_index"]
[_tb_end_tyrano_code]

[button target="*nextpage" graphic="arrow_next.png" x="800" y="590" storage="" width="50" height="50" ]
[tb_start_tyrano_code]
[endif]
[_tb_end_tyrano_code]

[s ]
*backtitle

[cm ]
[tb_start_tyrano_code]
[freeimage layer=1]
[_tb_end_tyrano_code]

[jump storage="title_screen.ks" target="*title" ]
*nextpage

[tb_start_tyrano_code]
[emb exp="tf.page++;"]
[_tb_end_tyrano_code]

[jump target="*cgpage" storage="" ]
*backpage

[tb_start_tyrano_code]
[emb exp="tf.page--;"]
[_tb_end_tyrano_code]

[jump target="*cgpage" storage="" ]
*clickcg

[cm ]
[tb_start_tyrano_code]
[image storage=&tf.selected_cg_image folder="default" ]
[l]
[_tb_end_tyrano_code]

[bg time="300" method="crossfade" storage="title.jpg" ]
[jump target="*cgpage" storage="" ]
[s ]
*no_image

[jump target="*cgpage" storage="" ]


ver1.3、windowsで制作しています。

どうぞよろしくお願いします。
16:のの :

2015/10/14 (Wed) 00:57:53

>>15
どうやら「cg.ks」の画像指定先が「bgimage」ではなく「default」になっているようです。
「default」フォルダを作成してそちらに画像を入れるか、
 もう一度「cg.ks」を入れなおし「bgimage」に指定されているか確認してみてはいかがでしょうか。
17:dd :

2015/10/14 (Wed) 14:51:54

>>16
のの様

ご指摘の部分を見直して改変したところ無事画像が出てくるようになりました!
ありがとうございました!!
18:g :

2015/11/12 (Thu) 14:31:46

ノベルブースターを組み込みCGモードに登録した画像が表示されたまではいいですが、サムネイルをクリックしても反応がありません。
他は正常に機能しているようですが、これだけは対処法が見つかりません。
使用ツールはPro版の1.4です。助言できる方、お願いします。
19:キック :

2015/12/15 (Tue) 06:51:31

18のg様と同じで、サムネイルをクリックしても反応がありません。
いろいろと試してみましたが、力不足でどうにもなりませんでした。
助言していただけたら幸いです。
20:  :

2016/02/13 (Sat) 06:06:52

ここに書かれている通り1.4にて安定してCGモードを動かせたのですが、
1.5へバージョンを移行すると機能しない状態です。
色々と試したのですが知識に乏しく自分では実現できていません。
どなたか親切な方、方法をご存知の方はいませんか?
21:  :

2016/02/13 (Sat) 07:02:42

>>20ですが自己解決しました。

ティラノスクリプトv400以降のtyrano.ksとcg.ksをコピーしたら戻りました。
CGモードの作りかたというスレも何か書き直した方がよさそうですね。
22:sawa :

2016/02/19 (Fri) 02:42:56

>>20 
「ティラノスクリプトv400以降のtyrano.ksとcg.ksをコピーしたら戻りました。」
というのは、バックアップを取っておいた上記二つのksを上書きすれば良いと言う事でしょうか?
上書きしてみたのですが、上手く行きません。
上手く1.5バージョンへ以降できず、困っております。
お力添えいただけたら嬉しいです。
よろしくお願いします。
23:yui :

2016/03/04 (Fri) 20:16:58

はじめまして。

こちらの書き込みを参考に試行錯誤した結果、なんとかCGモードと回想モードが設置と可動できました。
しかし更に難題にぶつかり、どれだけ調べても解決方法が見当たらないため質問させて下さい。

【起きている問題】
まず、メッセージウィンドウの上に小さなメニューボタン(saveやlogなど)を配置しています。
その上で、タイトル画面から「はじめから」というボタンをクリックしてゲームを進めると
上記メニューボタンは問題なく表示されています。
しかし、タイトル画面から「CGモード」または「回想モード」いずれかをクリックし、
一度対象のページに入り、そのページから「タイトルへ戻る」をクリック(*backtitle)で戻り、
再度「はじめから」でスタートするとメニューボタンが消えてしまいます。

「はじめから」でtitle_screen.ksから始めると表示されるのに、
CG(cg.ks)及び回想モード(replay.ks)から*backtitle指示で始めると表示されないので、
この辺りが問題のような気がするのですが、解決方法がわかりません。

どなたかおわかりになりましたらご教授下さい。
宜しくお願い致します。
24:メモ :

2016/03/06 (Sun) 15:09:55

clearfixかfreeimageでcg選択ボタンを決してませんか? 画面初期化
この場合はメニューボタンのスクリプトを張っておけば直ります
>>15さんのようにスクリプトを張って頂けるとスクリプトがわかる方も答えやすいです
25:yui :

2016/03/06 (Sun) 16:11:39

24:メモさん
ありがとうございます!
おっしゃる通り、CG及び回想モードの*backtitleの下にそれぞれ[freeimage layer=1]となっていました。
ですので教えて頂いた通りにメニューボタンのスクリプトをすぐ下に記述したら直りました。
まだレイヤーの仕組みがわかっていないので、どうしてこれで直るのかは理解できてませんが、
また勉強していこうと思います。

また質問があった時にはスクリプトも貼るように致します。
本当に感謝です!!
26:メモ :

2016/03/06 (Sun) 18:51:48

よかった。
シーンのクリアには
メッセージを非表示 @layopt layer=message0 visible=false (消去はせず非表示
メニューボタンの消去 @clearfix
指定レイヤーの表示物消去 @freeimage layer=1 数値が使われています
27:yui :

2016/03/08 (Tue) 18:36:37

度々失礼致します…
できたらいいな、という程度ですが、もしおわかりになる方がいたらご教授下さい。

今度はCGモード内でのことなんですが、今回「cg.ks」をコピーして「cg2.ks」「cg3.ks」を作り、
ジャンプ機能で飛ばす方法を取っています。(他にいい方法がある気もしますが。。)
その際、2ページ目にて見たいサムネイルをクリックし、CGが拡大されている状態で画面クリックで一覧に戻りますが、
1ページ目(cg.ks)のサムネイル一覧になってしまいます。(3ページ目でも同様です。)
プレイヤーの方にとっては不便かと思いますので、できれば直したいです。
しかし、どこを触ればいいのかがわかりません。

以下、「cg2.ks」のスクリプトを貼っておきますので、お願いします。


[_tb_system_call storage=system/_cg2.ks]

[layopt layer=message0 visible=false]

[clearfix]

[hidemenubutton]

[cm ]
[bg storage="cgbg.png" time="1000" ]
[layopt layer=1 visible=true]

[ptext layer=1 page=fore text="CGモード" x=20 y=20 size=26 color=0xA8401C visible=true]

[iscript]
tf.page = 0;
tf.selected_cg_image = ""; //選択されたCGを一時的に保管
[endscript]

*cgpage

[cm ]
[button graphic="back_title.png" target="*backtitle" x="790" y="20" storage="" ]
[iscript]
tf.tmp_index = 0;
tf.cg_index = 12 * tf.page;
tf.top = 100;
tf.left = 60;
[endscript]

[iscript]
tf.target_page = "page_"+tf.page;
[endscript]

*cgview

[jump target="&tf.target_page" storage="" ]
*page_0

[cg_image_button graphic="s4/13.jpg" no_graphic="noise.jpg" x=35 y=100 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s4/14.jpg" no_graphic="noise.jpg" x=265 y=100 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s4/15.jpg" no_graphic="noise.jpg" x=495 y=100 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s5/16.jpg" no_graphic="noise.jpg" x=725 y=100 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s5/17.jpg" no_graphic="noise.jpg" x=35 y=280 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s5/18.jpg" no_graphic="noise.jpg" x=265 y=280 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s5/19.jpg" no_graphic="noise.jpg" x=495 y=280 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s6/20.jpg" no_graphic="noise.jpg" x=725 y=280 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s6/21.jpg" no_graphic="noise.jpg" x=35 y=460 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s6/22.jpg" no_graphic="noise.jpg" x=265 y=460 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s7/23.jpg" no_graphic="noise.jpg" x=495 y=460 width=200 height=150 folder="bgimage" ]

[cg_image_button graphic="s7/24.jpg" no_graphic="noise.jpg" x=725 y=460 width=200 height=150 folder="bgimage" ]

[button storage="cg.ks" target="" graphic="backpage.png" width="80" height="25" x="35" y="640" ]
[button storage="cg3.ks" target="" graphic="nextpage.png" width="80" height="25" x="845" y="640" ]
[jump target="*common" storage="" ]
*common

*endpage

[s ]
*backtitle

[cm ]
[freeimage layer=1]

[button role="save" graphic="buttons/save.png" x="350" y="480" width="120" height="40" visible="false" storage="" target="" ]
[button role="load" graphic="buttons/load.png" x="480" y="480" width="120" height="40" visible="false" storage="" target="" ]
[button role="title" graphic="buttons/title.png" x="740" y="480" width="120" height="40" visible="false" storage="" target="" ]
[button role="backlog" graphic="buttons/backlog.png" x="610" y="480" width="120" height="40" visible="false" storage="" target="" ]
[button role="window" graphic="buttons/window.png" x="830" y="660" width="30" height="30" visible="false" storage="" target="" ]
[jump storage="title_screen.ks" target="" ]
*nextpage

[emb exp="tf.page++;"]

[jump target="*cgpage" storage="" ]
*backpage

[emb exp="tf.page--;"]

[jump target="*cgpage" storage="" ]
*clickcg

[cm ]
[image storage=&tf.selected_cg_image folder="bgimage" ]

[l]

[bg storage="cgbg.png" time="10" ]
[jump target="*cgpage" storage="" ]
[s ]
*no_image

[jump target="*cgpage" storage="" ]


無知ですみません。宜しくお願い致します。
28:メモ :

2016/03/09 (Wed) 20:27:19

cgモードのページの増やし方がはラベルを増やすだけでいいようです。
ジャンプボタンで必ずnextpageに飛べばいいようです。
見たところ、いろいろ変えているようなので・・・
ティラノスクリプトwiki管理人さんが教えてくれましたので、まずは、そちらを見た方がいいと思います
(それで、またわからなかったらここに書いてください)
29:メモ :

2016/03/09 (Wed) 22:07:42

バージョンが新しいtyrano.ks と同じように見えます
cg.ksファイル自体は増やさないで、可能です。内容を壊していないなら
*nextpageにジャンプし続ければ次のページとして再描画されます。
その前に
ページ数を増やす場合 *page_1 *page_2とブロックごとにラベルを増やしてください。

*page_1
[cg_image_button graphic="toile.jpg" no_graphic="noise.jpg" x=60 y=100 width=160 height=140 folder="bgimage" ]
ここに [cg_image_button ]を増やしていく
@jump target="*common"




このスクリプトは、ジャンプに対する制御や流れの知識が必要かと思います
30:yui :

2016/03/09 (Wed) 23:55:12

28-29.メモさん

スゴい!できました!!
今回も教えて下さってありがとうございます。

ティラノスクリプトwiki管理人さんのページ、知らなかったです。
確認不足ですみませんでした。
これからはわからなかったら一度管理人さんのページをチャックしてみます。

やはりページの増やし方がまずかったのですね。。
ありがとうございました。またお願い致します。
31:エミル :

2016/03/13 (Sun) 19:53:32

ののさんのやり方通りに作ってみたんですが、cg.ksが23行目41行目でエラーを吐いてしまいます…
cg.ksの中身を貼らせていただきますのでどこが原因なのかご教授いただけると幸いです。


;=========================================
; CG モード 画面作成
;=========================================

[cm]



[back storage="cgbg.png"]
[layopt layer=1 visible=true]
[ptext layer=1 page=fore text="CGモード" x=20 y=20 size=26 color=white visible=true]


[iscript]

tf.page = 0;
tf.cg_index = 0;

tf.cg_length = tf.cg_array.length;

tf.selected_cg_image = ""; //選択されたCGを一時的に保管

[endscript]



*cgpage
[cm]
[button graphic="back_title.gif" target="*backtitle" x=800 y=20 ]

[iscript]
tf.tmp_index = 0;
tf.cg_index = 12 * tf.page;
tf.top = 100;
tf.left = 60;

[endscript]

*cgview

[if exp ="sf.cg_viewd[tf.cg_array[tf.cg_index]]" ]

[button graphic=&tf.cg_array[tf.cg_index] x=&tf.left y=&tf.top width=160 height=140 exp="tf.selected_cg_image = tf.cg_array[preexp]" target="*clickcg" folder="bgimage" preexp="tf.cg_index" ]

[else]

[button graphic=noise.jpg x=&tf.left y=&tf.top width=160 height=140 folder="bgimage" target="*no_image"]

[endif]

[iscript]

tf.tmp_index++;
tf.cg_index++;
tf.left += 160 + 60;

[endscript]

;1ページに12 枚

[if exp=" tf.tmp_index == 12 || tf.cg_index >= tf.cg_length"]
@jump target="*endpage"
[endif]

[if exp="tf.tmp_index % 4 == 0 "]
[iscript]
tf.top += 140 + 30;
tf.left = 60;
[endscript]
[endif]

@jump target="*cgview"

*endpage

[if exp="tf.page !=0"]

[button target="*backpage" graphic=backpage.gif x=640 y=600 ]

[endif]

[if exp="tf.cg_length > tf.cg_index"]

[button target="*nextpage" graphic=nextpage.gif x=800 y=600 ]

[endif]


[s]

*backtitle
[cm]
[freeimage layer=1]
@jump storage=title_screen.ks

*nextpage
[emb exp="tf.page++;"]
@jump target="*cgpage"


*backpage
[emb exp="tf.page--;"]
@jump target="*cgpage"

*clickcg
[cm]
[image storage=&tf.selected_cg_image folder="bgimage" ]
[l]
[back storage="cgbg.png" time=10]
@jump target=*cgpage
[s]

*no_image

@jump target=*cgpage



32:ダイス :

2016/03/13 (Sun) 21:13:21

回想モードについてなのですが、回想用として別のscenario.ksから回想用ファイルを作った後に
飛ばす方法はあるでしょうか?
プレビュー時に全部表示されていたので、いざ書き出した後に気付いたらまるで表示されませんでした。

[setreplay name="回想4" storage="scene4last.ks" target="*おしかけ4"]
*回想4

[if exp="tf.flag_replay==true"]
  [position layer="message0" left=20 top=400 width=920 height=200 page=fore visible=true]
  [position layer=message0 page=fore margint="45" marginl="50" marginr="70" marginb="60"]
  @layopt layer="message0" visible=true
[endif]


[endreplay]

別途nobel_vooster記載。

回想モードに登録される
image = 回想モードで表示される画像を指定できます。
storageとtarget = 回想の開始地点位置をファイルとラベルを指定します

*/

tf.replay_array = [

{image:"015.jpg",storage:"r_scene4last.ks",target:"*回想4"},
{image:"026.jpg",storage:"r_scene5.ks",target:"*回想5"},
{image:"030.jpg",storage:"r_scene6_3.ks",target:"*回想6_3"},

よろしくお願いします。
33:ダイス :

2016/03/14 (Mon) 18:56:34

現状は無理矢理直通させるやり方で解決しました。
ルート通過で開放じゃないですが、今回は気にしなければいいかなぁと思いました。
[button graphic="015.jpg" x=60 y=100 width=160 height=140 folder=bgimage storage=r_scene4last.ks target=*回想4]
34:メモ :

2016/03/15 (Tue) 04:23:18

>>31 プロジェクトから直接 cg.ksをテキストエディターで開いて何行目に何が書いてあるか把握しないと難しいですね
一番は、新しいティラノスクリプトからcg.ksをダウンロードできたらいいのですが
http://tyranobuilder.wiki.fc2.com/wiki/%E3%83%86%E3%82%A3%E3%83%A9%E3%83%8E%E3%82%B9%E3%82%AF%E3%83%AA%E3%83%97%E3%83%88%E3%81%8B%E3%82%89%E3%81%AE%E3%83%93%E3%83%AB%E3%83%80%E3%83%BC%E3%81%B8%E3%81%AE%E7%A7%BB%E6%A4%8D
35:エミル :

2016/03/15 (Tue) 09:42:49

>>34 最新のティラノスクリプトから引っ張ってきたら出来ました!!
メモさんご相談にのっていただきありがとうございました!!
36:みるく :

2016/03/27 (Sun) 18:31:57

横からすいません

新しいティラノスクリプトからcgksそのまま持って来て使えるかなと思ったんですが、
タグ[cg_image_button]は存在しません。というエラーが出て止まってしまいます。
これはどうすればいいでしょうか…。
37:メモ :

2016/03/27 (Sun) 18:45:03

リンクに飛んで一番下をみてもらうとわかりますが、tyrano.ksも必要です
たぶんエンジンも一緒にした方がいいと思います

cg_buttan ティラノスクリプトwiki
http://tyrano.wiki.fc2.com/wiki/CG%E3%83%A2%E3%83%BC%E3%83%89%E3%81%AB%E3%81%A4%E3%81%84%E3%81%A6%E3%81%AE%E8%BF%BD%E8%A8%98?pc

ファイル構成 tyranoというフォルダがエンジン ティラノビルダーwiki
http://tyranobuilder.wiki.fc2.com/wiki/%E3%83%95%E3%82%A1%E3%82%A4%E3%83%AB%E6%A7%8B%E6%88%90
※互換性は保証しませんのでバックアップしてから
38:メモ :

2016/03/27 (Sun) 19:01:40

あと >>34のリンク内も、きっちり読んでいただければ詳細が書かれています
39:エミル :

2016/03/31 (Thu) 21:47:12

またまた質問すみません

スチルの表示の比率を変えたくてここに書いてくださっているとおりに
widthとheightの数値を変更したのですが、画像の比率が変わりません…
どうしてでしょうか?
cd.ksの中身を貼らせていただきますのでご教授よろしくお願いします…

[_tb_system_call storage=system/_cg.ks]

[layopt layer=message0 visible=false]

[clearfix]

[hidemenubutton]

[cm ]
[stopbgm time="1000" ]
[playbgm volume="20" time="1000" loop="true" storage="和風たゆたうとき.ogg" ]
[bg storage="cgbg.png" time="100" ]
[layopt layer=1 visible=true]

[ptext layer=1 page=fore text="CGモード" x=20 y=20 size=30 color=white visible=true]

[iscript]
tf.page = 0;
tf.selected_cg_image = ""; //選択されたCGを一時的に保管
[endscript]

*cgpage

[cm ]
[button graphic="back_title.gif" target="*backtitle" x="800" y="20" storage="" ]
[iscript]
tf.tmp_index = 0;
tf.cg_index = 12 * tf.page;
tf.top = 100;
tf.left = 60;
[endscript]

[iscript]
tf.target_page = "page_"+tf.page;
[endscript]

*cgview

[jump target="&tf.target_page" storage="" ]
*page_0

[cg_image_button graphic="toile.jpg" no_graphic="noise.jpg" x=60 y=100 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="entrance.jpg" no_graphic="noise.jpg" x=260 y=100 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=450 y=100 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="room.jpg" no_graphic="noise.jpg" x=640 y=100 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=60 y=260 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=260 y=260 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=450 y=260 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=640 y=260 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=60 y=420 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=260 y=420 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=450 y=420 width=140 height=93 folder="bgimage" ]

[cg_image_button graphic="rouka.jpg" no_graphic="noise.jpg" x=640 y=420 width=140 height=93 folder="bgimage" ]

[jump target="*common" storage="" ]
*page_1

[button graphic="backpage.gif" target="*backpage" x="100" y="600" storage="" ]
[jump target="*common" storage="" ]
*common

*endpage

[s ]
*backtitle

[stopbgm time="1000" fadeout="true" ]
[cm ]
[freeimage layer=1]

[jump storage="title_screen.ks" target="*title" ]
[emb exp="tf.page++;"]

[jump target="*cgpage" storage="" ]
*backpage

[emb exp="tf.page--;"]

[jump target="*cgpage" storage="" ]
*clickcg

[cm ]
[image storage=&tf.selected_cg_image folder="bgimage" ]

[l]

[bg storage="cgbg.png" time="10" ]
[jump target="*cgpage" storage="" ]
[s ]
*no_image

[jump target="*cgpage" storage="" ]

40:エミル :

2016/03/31 (Thu) 22:27:41


すみません、解決しました…
tyrano.ksのここをいじったら比率変わりました!
私と同じ疑問がある方は参考までにどうぞ!!


;渡された値を元に、CG状態を確認していく
[if exp="tf.is_cg_open==true"]
[button graphic=&mp.graphic x=&mp.x y=&mp.y width=160 height=107 preexp="mp.graphic" exp="tf.selected_cg_image = preexp" storage="cg.ks" target="*clickcg" folder="bgimage" ]
[else]
[button graphic=&mp.no_graphic x=&mp.x y=&mp.y width=160 height=107 storage="cg.ks" target="*no_image" folder="bgimage" ]
[endif]
[endmacro]


;渡された値を元に、CG状態を確認していく
のところのwidthとheightの数値を変更してみてください。

あくまで参考までにどうぞ^^
41:エミル :

2016/03/31 (Thu) 22:54:20

ふと思ったんですが、
CGモードでCGをクリックして拡大表示(原寸大表示でしょうか?)にした後、
そこから一覧に戻るのではなく表情差分を表示して、
そしてもう一度クリックしたら一覧に戻るようにしたいです。

CG一覧
 ↓
CG
 ↓
CG(表情差分など)
 ↓
CG一覧


その方法が思いつかなくて、困っています。

ぜひご教授願います…。

42:メモ :

2016/04/01 (Fri) 07:56:15

>>40 勉強になりました ありがとうございます
cg解放されたcgボタンの飛ぶ先は、*clickcg のようなので? それを見ると

[cm]ボタンを消す
[image storage=&tf.selected_cg_image folder="bgimage" ]

&tf.selected_cg_image エンティティで渡された画像名、フォルダはbaimageで表示して下さいという形なので、
新しく*clickcg2を作って そこに飛び
先に表示したimageにnameをつけてクリック[l]したらname指定でfreeimage イメージ消す
その後に差分用のイメージ表示というものなら出来るかもしれません ただあんまり多いと、ジャンプ先が増えてコードが
見づらくなってしまいますよね…

あと新しくtyrano.ksからcgボタンを作成しないといけないですし
;macro name=cg_buttan2
;渡された値を元に、CG状態を確認していく
[if exp="tf.is_cg_open==true"]
[button graphic=&mp.graphic x=&mp.x y=&mp.y width=160 height=107 preexp="mp.graphic" exp="tf.selected_cg_image = preexp" storage="cg.ks" target="*clickcg2" folder="bgimage" ]
;targetを変更した新しいcg_buttan2というマクロを作成
[else]
[button graphic=&mp.no_graphic x=&mp.x y=&mp.y width=160 height=107 storage="cg.ks" target="*no_image" folder="bgimage" ]
[endif]
[endmacro]






*clickcg2|新しい差分有り用
[cm ]
[image name=sabun1 storage=&tf.selected_cg_image folder="bgimage" ]

[l];クリック待ち 押したら消えて新しいimage表示
[freeimage name=sabun1]
[image storage=sabun2.jpg folder="bgimage" ];ここが固定のイメージになってしまう
;ボタンを押したときに変数で分岐すればいいかもしれない
[l];クリック待ち 押したら戻る
[bg storage="cgbg.png" time="10" ]
[jump target="*cgpage" storage="" ]
[s ]

ほぼティラノスクリプトの話題ですので、解決できなかったらティラノスクリプトの板で聞いた方がいいかもしれません
43:ごま :

2016/05/13 (Fri) 01:29:40

はじめて書き込ませていただきます! ティラノビルダー初心者です。

たぶん、CGモードは実装はできたのかな?
最初は、[cg_image_button]は存在しません とエラーが出てしまって。。。あれ? となっていましたが、
最新のティラノスクリプトのtyrano.ksファイルを製作しているゲームのtyrano.ksファイルに上書きしましたら、
エラーも出なかったので、できたのかなー?という感じなのですけど。。

ここから本題なのですが、はじめから でゲームを開始する時と、
セーブした状態でロードして つづきから でゲームを開始する時は、
自前のUIデザインボタンの、スキップ、セーブ、ロード、メッセージオフは表示されているので問題ないのですが。

ゲームを立ち上げてから、ギャラリーを開いた状態からタイトルに戻って、
はじめから でゲームを開始すると自前のスキップ、セーブ、ロード、メッセージオフのボタンが消えてしまいます。

立ち上げてから → ギャラリーへ → タイトルに戻る → つづきから は問題なくボタンの方は表示されています。

立ち上げてから → キャラリーへ → タイトルに戻る → はじめから → ボタン消失 という感じです。

うーん、どこがどう間違っているのか全くわからない状態です。、
44:ごま :

2016/05/14 (Sat) 06:11:17

すみません。解決しました!!

UIデザインで設定したボタンが
message_window.ksファイルに記載されていました。


[button role="save" graphic="セーブ.png" x="683" y="597" width="90" height="33" visible="false" ]
[button role="load" graphic="ロード.png" x="784" y="600" width="86" height="28" visible="false" ]
[button role="skip" graphic="スキップ.png" x="595" y="600" width="78" height="31" visible="false" ]
[button role="window" graphic="メッセージオフ.png" x="881" y="594" width="56" height="31" visible="false" ]


↑こちらのスクリプトをcg.ksファイルにある

*backtitle

[cm ]
[freeimage layer=1]

の後に記述、上の方がおっしゃっている通りにしましたら、ギャラリーからタイトルに戻って、ゲームを始めるでスタートした時にも、
ちゃんとボタンが表示されていました!
45:かどう :

2016/06/15 (Wed) 15:29:22

お世話になっております。
CGモードを追加したのですが、タイトルからストーリーに進んでから
またタイトルに戻り、そしてギャラリーに行くとエラーがでます。

cg.ksにて

[_tb_system_call storage=system/_cg.ks]

[cm ]
[back storage="cgbg.png"]

[layopt layer=1 visible=true]

[ptext layer=1 page=fore text="CGモード" x=20 y=20 size=26 color=white visible=true]

[iscript]
tf.page = 0;
tf.cg_index = 0;
tf.cg_length = tf.cg_array.length;
tf.selected_cg_image = ""; //選択されたCGを一時的に保管
[endscript]   ←ここでエラーがでるのです。

CGページは真っ黒で画像もでません。
すみませんが、どなたかご教授いただけると助かります。
46:かどう :

2016/06/15 (Wed) 16:53:19

>45
すみません、上記の件はなんとか事故解決できました。CGページも表示されました。

しかしまた次のエラーがでてしまって困っています。
表示したい背景の下にティラノスクリプトを入れて


[bg time="3000" method="crossfade" storage="A_001.png" ]
[iscript]
[cg storage="A_001.png"]
[endscript]

このように入れているのですが、

[cg storage="A_001.png"] ここでエラーがでてしまいます。

すみませんが、どなたかご教授いただけると助かります。
47:P10 :

2016/09/02 (Fri) 07:26:29

ティラノビルダーのCGモード未だに解決出来ず、早1年が経とうとしている。
CGやテキストよりもCGモードの作業のが多いという。
もうCGモードは無しでいいかな…。
48:P10 :

2016/09/04 (Sun) 08:57:24

再度、色々調べた所。
最新のティラノスクリプトのCG.ksを導入すれば全て解決します。
ブースターパックのCG.ksは古くて合わないみたいです。

後は>>1 にあるように
*backtitle
[cm]
[freeimage layer=1]
@jump storage=title_screen.ks

するだけです。
シケモク氏はちゃんと進歩したモノを作っていました。
49:haru :

2016/11/12 (Sat) 22:41:32

このスレを参考にCGモード導入できました、ありがとうございます!
しかし質問用スレッドやこのスレの>>18>>19で出てるような
トラブルで行き詰まってしまいました

CGモードは導入できたものの、開放されたCGのサムネをクリックしても
CGが原寸表示(拡大表示)されない、というものです
ここをクリアすればもうCGモードは完成なのでかなり悔しい状態です

何件か書かれていて自分も困っているので改めて書いてみました
もしこうすれば直ったよ!という方がいらっしゃったら
解決法を書いてくださるとありがたいです、自分でも探してみようと思います。

  • 名前: E-mail(省略可):
  • 画像:

Copyright © 1999- FC2, inc All Rights Reserved.